Start a new Scratch project, and delete the cat sprite so that your project is empty. You can find the online Scratch editor at jumpto.cc/scratch-new.

For this project, you should have a ‘Project Resources’ folder, containing all of the images you’ll need. Make sure that you can find this folder, and ask your club leader if you can’t find it.

From this ‘Project Resources’ folder, import ‘background.png’ as the stage backdrop and ‘boat.png’ as a new sprite. If you don’t have these images you can draw them yourself!

Rename your sprite ‘Player 1’, shrink it slightly, and move it to the bottom of the stage.

Your project should look like this:

You are going to control the boat with your mouse. Add this code to your boat:

    when flag clicked
    point in direction (0 v)
    go to x: (-215) y: (-160)
    forever
        point towards [mouse-pointer v]
        move (1) steps
    end

Test out your boat, by clicking the flag and moving the mouse. Does the boat sail towards the mouse?

Have a look what happens when the boat reaches the mouse pointer.

To stop this happening, you’ll need to add an if block to your code, so that the boat only moves if it is more than 5 pixels away from the mouse.

    when flag clicked
    point in direction (0 v)
    go to x: (-215) y: (-160)
    forever
        if < (distance to [mouse-pointer v]) > [5] > then
            point towards [mouse-pointer v]
            move (1) steps
        end
    end

Test out your boat again, to check whether the problem has been fixed.

Add a new variable called time to your stage. You can also change the display of your new variable. If you need help, have a look at the ‘Balloons’ project.

Add this code to your stage, so that the timer counts up until the boat reaches the desert island:

    when flag clicked
    set [time v] to [0]
    forever
        wait (0.1) secs
        change [time v] by (0.1)
    end

That’s it! Test out your game and see how quickly you can get to the desert island!

First let’s add some ‘boosts’ to your game, which will speed up the boat. Edit your stage backdrop and add in some white booster arrows.

You can now add some code to your boat’s forever loop, so that it moves 2 extra steps when touching a white booster.

    if <touching color [#FFFFFF]?> then
        move (3) steps
    end

You can also add in a spinning gate, which your boat has to avoid. Add in a new sprite called ‘Gate’, which looks like this:

Make sure that the colour of the gate is the same as the other wooden barriers.

Set the center of the gate sprite.

Add this code to your gate, to make it spin slowly:

    when flag clicked
    forever
        turn right (1) degrees
    end

Test out your game. You should now have a spinning gate that you must avoid.